// This dialogue is obsolete now. It was a force talk for Aerie to break the romance whenever the player wanted. It is not proof readed and is hard coded. Feel free to uncomment it so you will see it in the game, but ONLY if you don't have the flirt packs installed.
APPEND AERIEJ
IF WEIGHT #999
~!Global("PhaereFixMRAe","GLOBAL",1)~
THEN BEGIN MRDC1
SAY @4723
IF ~Global("AerieMR","GLOBAL",1)~ THEN REPLY ~Nothing... just to tell you that I still love you, Aerie.~ GOTO BAMR3
IF ~Global("AerieMR","GLOBAL",1)~ THEN REPLY ~Aerie... I don't know how to put this. The fact is that, well... I think our relationship is a mistake.~ GOTO BAMR1
IF ~Global("AerieMR","GLOBAL",1)~ THEN REPLY ~I think loving a pathetic wingless Avariel was the most stupid mistake I've ever made. We are over, girl, go whine somewhere else.~ GOTO BAMR2
IF ~Global("HadImoenDreamRomance2","GLOBAL",1)
Global("WeTalkedOfItAlready","LOCALS",0)~ THEN REPLY @4724 DO ~SetGlobal("WeTalkedOfItAlready","LOCALS",1) ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRDC2
IF ~~ THEN REPLY @4562 GOTO MRDC1a
END
IF ~~ THEN BEGIN BAMR1
SAY ~I, ah... w-what? You... you are not serious, are you...?~
IF ~~ THEN REPLY ~I am. It's... the best for the group, and for us... please, don't be upset... I still appreciate you too much to see you leave, please stay with me, as my friend...~ GOTO BAMR4
IF ~~ THEN REPLY ~OF COURSE I am, you STUPID WENCH!! Are you so PATHETIC and WEAK that you can't understand it!? I hate your WHINES, I hate YOU!!~ GOTO BAMR2
END
IF ~~ THEN BEGIN BAMR2
SAY ~(Aerie gasps, taking a step back. Her pointy ears virtually bleed from your cruel words, that have crossed through her brain like a destructive lightning, absolutely unexpected, utmostly painful.)~
=
~(Her eyes are wetting already against her will; her lips tremble. Breathing heavily, she is unable to utter a word for a while; what you have just told her, even if you weren't really serious, blocking her reasoning.)~
=
~(Crying, she turns around and leaves, simply unable to express with words the pain you have just caused her.)~
IF ~IsValidForPartyDialog("Imoen2")~ THEN DO ~GivePartyAllEquipment() LeaveParty() EscapeArea() ActionOverride(Player1,SetDialog("Player1"))~ EXTERN IMOEN2J BAMR2cha
IF ~!IsValidForPartyDialog("Imoen2")~ THEN DO ~GivePartyAllEquipment() LeaveParty() EscapeArea()~ EXIT
END
IF ~~ THEN BEGIN BAMR3
SAY ~(Aerie blushes and smiles, looking to the ground like a teenager in love would do, saying absolutely nothing but telling you with her expression that she really appreciates your words.)~
IF ~~ THEN EXIT
END
IF ~~ THEN BEGIN BAMR4
SAY ~(Aerie says nothing for a while, absolutely speechless, though this doesn't surprise her that much. Your attitude towards her has been distant lately... in her inner self she knew this would happen sooner or later, as she felt the bond between you two weakening more and more... she knew that it would be broken soon, but she is still surprised nevertheless.)~
=
~I... I am not stupid, <CHARNAME>... I know when something simply does not work... I... I have grown mature enough to see this... and mostly thanks to you. I would give us another chance if it was only my decision but... if you don't want it, then there's nothing left to keep between us.~
=
~It would be too selfish and unfair to leave you now, <CHARNAME>. But understand that... I will not be able to even look at your eyes like I am doing now in a long time...~
=
~I... I need some time to think... if you'll excuse me...~
IF ~!Global("NoReturnMR","GLOBAL",1) GlobalLT("Chapter","GLOBAL",5)~ THEN DO ~SetGlobal("AerieRomanceActive","GLOBAL",3) SetGlobal("ImoenRomanceActive","GLOBAL",1)~ EXIT
END
END
APPEND IMOEN2J
IF ~~ THEN BEGIN BAMR2cha
SAY ~Aerie, wait! No, don't leave... (Imoen looks at the elf, as her golden hair gradually gets out of sight...)~
=
~(Then she turns to you, and looks back to Aerie's frame once again, undecision in her face. Another quick glance... and she resists the urge to start running after the Avariel.)~
=
~I should leave you to rot here, you heartless bastard...~
=
~Goodbye, Aerie... I'll miss you...~
IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~ EXIT
END
END
