[Modding] Scripting Fragen

[Maus]

Danke schon mal. Mit MYAREA hat es funktioniert und MoveBetweenAreas dann auch.

[Gelöst]
Jetzt eine philosophische Frage fast:
Kann ich mit GlobalLT (2 z.B.) eine Variable abfragen, die nicht existiert? Ich dachte immer, wenn man Global (=0) abfrägt, dann hat man diesen Fall, weil "does not exist" halt =0 ist. Und 0 ist kleiner als 2. Aber der Skriptblock läuft nicht...
Ich probier das mal aus. Wenn ich die Variable vorher erstmal auf 1 setze und dann den GlobatLT abfrage...

Und noch zu LeaveAreaLUA: mein Verdacht wäre, dass das nur mit cre funktioniert, die in der GAM eingetragen sind. Weil ich nur Beispiele damit gefunden habe... Müsste ich mal in NI durchjagen, mal schauen.

edit: das Problem war, dass das Skript wegen eines fehlenden Continue() vorher fest hing und nicht weiter lief bis zur Stelle, wo ich die GlobalLT abgefragt habe...

 

[Maus]

Mal eine schwierige Frage zur Performance: Wie programmiere ich effizient, so dass das Spiel nicht langsamer wird. Mir kommt es so vor, wie wenn Installationen mit vielen Mods mit fortschreitender Spieldauer immer langsamer laufen. Da ergeben sich dann ein paar Fragen:

a) Korrekt, dass man besser keine Skript in die BALDUR.BCS schreibt, weil die praktisch permanent läuft? Lieber in Area-Skripte Trigger setzen, etc.?

b) Wie ist das mit den Variablen? Packt BG die einfach in einen Speicher, der sich immer mehr füllt und wo die Skripte dann nachschauen, wenn eine Variable in einem Trigger sitzt? Möglichst sparsam mit Variablen umgehen ist klar und vor allem wieder verwenden mit anderen Werten, wenn man sie nicht mehr benötigt, würde ich mal sagen.

c) Gibt es hinsichtlich Performance einen Unterschied zwischen globalen und lokalen Variablen? Sind die lokalen vielleicht irgendwo weggepackt, bis z.B. das Skript oder die Area wieder geladen werden? Oder ist es ziemlich egal, ob eine Variable global oder lokal definiert wird, weil sie alle im selben Speicherbereich bereit gehalten werden?

Gibt sonst wichtige Dinge, was man nicht machen sollte? Nicht so viele Timer, weil die immer mitlaufen, lieber auf Ereignisse triggern oder ähnliches?

 

[Taimon]

a) Korrekt, dass man besser keine Skript in die BALDUR.BCS schreibt, weil die praktisch permanent läuft? Lieber in Area-Skripte Trigger setzen, etc.?

Ja, so wenig wie möglich in die BALDUR.BCS packen.

b) Wie ist das mit den Variablen? Packt BG die einfach in einen Speicher, der sich immer mehr füllt und wo die Skripte dann nachschauen, wenn eine Variable in einem Trigger sitzt?

Die Variablen sind in unterschiedlichen Hashtables. Es gibt eine globale Tabelle, eine pro Area und eine pro Actor.

c) Gibt es hinsichtlich Performance einen Unterschied zwischen globalen und lokalen Variablen? Sind die lokalen vielleicht irgendwo weggepackt, bis z.B. das Skript oder die Area wieder geladen werden? Oder ist es ziemlich egal, ob eine Variable global oder lokal definiert wird, weil sie alle im selben Speicherbereich bereit gehalten werden?

Ich würde versuchen die globalen Variablen zu minimieren, aber generell ist ein Hashtable-Lookup eigentlich recht schnell. Der Zugriff auf die globale und die jeweilige Area-Hashtable könnte allerdings schneller sein als der Zugriff auf die Actor-Hashtable, da die Engine nicht erst das Actor-Objekt "akquirieren" muss. (Spielt wahrscheinlich kaum eine Rolle.)

Gibt sonst wichtige Dinge, was man nicht machen sollte? Nicht so viele Timer, weil die immer mitlaufen, lieber auf Ereignisse triggern oder ähnliches?

Wie an anderer Stelle schon erläutert: die meisten Timer sind auch nur Variablen und werden identisch behandelt.
Allgemeine Performance-Empfehlungen kann ich nicht geben, aber der generelle Tenor ist schon möglichst wenig global zu machen.

 

[Maus]

Da dann gleich die Nachfrage: Sind die Begleiter in der Gruppe auch Actors? Oder sind die automatisch geladen, weil ja eigentlich immer da?

In einem Lookup-Table muss man aber auch erstmal suchen, oder sind die prinzipiell sortiert? Ich kenne das eher so, dass man Sachen, die man schnell braucht, in Lookup-Tables packt anstatt sie zu berechnen oder über ne Funktion zu holen. Aber Lookup ist immer noch langsamer als sie gleich in den Arbeitsspeicher zu schreiben.
Daher hätte ich gesagt: je größer die Lookup-Table umso schlechter, da noch was reinzupacken. Und GLOBAL dürfte die größte sein Richtiges Verständnis oder nur gefährliches Halbwissen?

 

[Taimon]

Sind die Begleiter in der Gruppe auch Actors?

Ja. Mit Actors meine ich im Prinzip alles, was ein Skript ausführen kann. (Intern wird die Klasse "CGameAIBase" genannt.)
Dazu zählen alle CREs aber auch Türen, Traps, etc.

Oder sind die automatisch geladen, weil ja eigentlich immer da?

Geladen sind sie sicher, aber trotzdem muss vor einem Zugriff sichergestellt werden, dass niemand anderes gerade etwas an dem Objekt ändert. Deswegen gibt es eine Funktion, die den exklusiven Zugriff sicherstellt.

In einem Lookup-Table muss man aber auch erstmal suchen, oder sind die prinzipiell sortiert?

Hashtabellen funktionieren so, dass der Schlüssel (in diesem Fall der Variablenname) mittels einer Hashfunktion auf einen Zahlenwert abgebildet wird. Der Zahlenwert wird als Index in ein Feld genommen und an der Stelle steht dann der gesuchte Wert.
Rein theoretisch ist damit die Lookup-Zeit unabhängig von der Anzahl der Elemente. Praktisch gibt es aber irgendwann Kollisionen (selber Zahlenwert bei unterschiedlichen Schlüsseln), da man die Feldgröße auch nicht beliebig groß machen möchte.

Aber Lookup ist immer noch langsamer als sie gleich in den Arbeitsspeicher zu schreiben.

Ich denke, hier bringst du etwas durcheinander. Der Speicherort ist unabhängig von der Struktur.
Und heutzutage ist praktisch sowieso fast alles im RAM, was häufiger benötigt wird. Wir haben ja mittlerweile mehr als 640 KB zur Verfügung.

je größer die Lookup-Table umso schlechter, da noch was reinzupacken. Und GLOBAL dürfte die größte sein

Wie schon erwähnt ist die Lookup-Zeit theoretisch konstant, in der Praxis hat man aber 20-30% Kollisionen. Es hängt stark von der Güte der Hashfunktion und dem zur Verfügung stehenden Speicherplatz ab. Und wenn die Tabelle stetig wächst, muss man auch irgendwann das Feld, in dem die Werte gespeichert werden, vergrößern. (Dauert auch eine Weile.)
Mein Kommentar, dass der Zugriff auf die globale Tabelle schneller sein könnte, bezog sich nur darauf, dass das Spiel genau weiß, an welcher Speicheradresse die Tabelle steht. Bei den anderen muss man sich erst das Objekt holen. Der Zugriff innerhalb der Tabelle ist aufgrund der Kollisionen aber sicher langsamer.

 

[Maus]

Uh, das triggert jetzt bei mir Verständnisfragen...

Also die Hashfunktion macht aus dem dem Variablennamen einen numerischen Wert? Und die Tabelle hat nachher zwei Spalten (Hashwert und Variablenname) oder 3 Spalten (+Variablenwert)? Oder nur 2 Spalten (Hashwert und Variablenwert)?

Und wenn das Spiel einen Variablennamen hat, dann berechnet es den Hashwert davon über die Hashfunktion und schaut in der Tabelle nach? Und kann dann den Variablenwert dort finden?

Und Kollision würde heißen, dass zwei Variablennamen denselben Hashwert ergeben, korrekt? Ist die Hashfunktion bekannt, so dass man beim Auswählen von Variablennamen darauf Rücksicht nehmen könnte? Und wenn Kollisionen möglich sind, müsste weiter oben im Text die Tabelle ja schon immer Hashwert und Variablennamen enthalten, um die Richtigkeit der Zuordnung überprüfen zu können.

Und das macht deswegen Sinn, weil in der Tabelle die Hashwerte fest zuschrieben sind und nicht ein Pointer drüberlaufen muss, der prüft, wo der entsprechende Eintrag im Array steht? und dadurch wird die Zugriffszeit unabhängig von der Größe?

 

[Taimon]

Ich fürchte, wir driften hier ganz schön ab. Einige Sachen sind sicher auch implementierungsabhängig.

Aber ich versuch's trotzdem mal:
So eine Hashtabelle wird mit einer bestimmten initialen Größe erzeugt. Diese bestimmt die Größe des Feldes (Array).
Typischerweise ist das ein Array aus Pointern (Verweise) auf Listen. (Es hat im Speicher also eigentlich nur eine Spalte. Wenn man den Index dazuzählen würde, wären es zwei.)
Die Listen wiederum verwalten alle Elemente für den jeweiligen Hashwert. Bei Kollisionen stehen also mehrere Elemente in der Liste. (Das Element ist das eigentliche Datum, hier wäre es der Variablenname und -wert.)
Initial sind die Listen alle leer. (Wahrscheinlich so umgesetzt, dass der Pointer NULL ist.)
Wenn man einen Wert zu der Hashtabelle hinzufügt, wird über die Hashfunktion ein Eintrag im Array selektiert. Dazu wird der Hashwert vom Schlüssel (Variablenname) gebildet.
Das hinzuzufügende Element wird dann einfach an die jeweilige Liste angehängt. Wenn es keine Kollisionen gibt, hat die Liste nur einen Wert.
Beim Lookup passiert quasi dasselbe, nur das der Wert von dem Element zurückgegeben wird. (Bei Kollisionen muss die Liste nach dem richtigen Variablennamen durchsucht werden.)

Ist die Hashfunktion bekannt, so dass man beim Auswählen von Variablennamen darauf Rücksicht nehmen könnte?

Kann man sicherlich recherchieren, aber ich würde darauf vertrauen, dass die meisten Implementierungen hier schon eine passende Funktion ausgewählt haben.
Also keine Rücksicht darauf nehmen.

 

[Maus]

Ich verstehen Jastey XP-Anpassungs-Skript nicht. Und stelle daher hier mal die Frage, bevor das im anderen Thread ausufert.

Erstmal noch hier der Code, den ich ein wenig verkürze, damit es besser passt:

/* Level 5 */

IF
InParty(Myself)
Global("C#BE_LevelUp","LOCALS",0) GlobalLT("C#LevelUp","LOCALS",5)
XPGT(Player1,15999)
XPLT(Myself,16000)
XPGT(Myself,7999)
CheckStat(Player1, 0, LEVELDRAIN)
THEN
RESPONSE #100
SetInterrupt(FALSE)
SetGlobal("C#LevelUp","LOCALS",5)
AddXPObject(Myself,8000)
SetInterrupt(TRUE)
END


/* Level 4 */

IF
InParty(Myself)
Global("C#BE_LevelUp","LOCALS",0) GlobalLT("C#LevelUp","LOCALS",4)
XPGT(Player1,7999)
XPLT(Myself,8000)
XPGT(Myself,3999)
CheckStat(Player1, 0, LEVELDRAIN)
THEN
RESPONSE #100
SetInterrupt(FALSE)
SetGlobal("C#LevelUp","LOCALS",4)
AddXPObject(Myself,4000)
SetInterrupt(TRUE)
END


/* Level 3 */

IF
InParty(Myself)
Global("C#BE_LevelUp","LOCALS",0) GlobalLT("C#LevelUp","LOCALS",3)
XPGT(Player1,3999)
XPLT(Myself,4000)
XPGT(Myself,1999)
CheckStat(Player1, 0, LEVELDRAIN)
THEN
RESPONSE #100
SetInterrupt(FALSE)
SetGlobal("C#LevelUp","LOCALS",3)
AddXPObject(Myself,2000)
SetInterrupt(TRUE)
END

/* Level 2 */

IF
InParty(Myself)
Global("C#BE_LevelUp","LOCALS",0) Global("C#LevelUp","LOCALS",0)
XPGT(Player1,1999)
XPLT(Myself,2000)
CheckStat(Player1, 0, LEVELDRAIN)
THEN
RESPONSE #100
SetInterrupt(FALSE)
SetGlobal("C#LevelUp","LOCALS",2)
AddXPObject(Myself,2000)
SetInterrupt(TRUE)
END

IF
InParty(Myself)
Global("C#BE_LevelUp","LOCALS",0)
THEN
RESPONSE #100
SetGlobal("C#BE_LevelUp","LOCALS",1)
END

So, und jetzt das Problem:
NPC hat 2500 XP, der HC hat 12000 XP. Dann ist der "Level-3 Block" true und wird ausgeführt und der NPC bekommt 2000 XP und hat dann 4500 XP. Die Blocks vorher werden nicht ausgeführt, weil XPGT(Myself,ab) nicht true ist. Die späteren Blocks werden nicht ausgeführt wegen der LevelUp-Variable die gesetzt wird (und weil die XPLT Bedingung nicht erfüllt ist).

Ich dachte zuerst, dass für jeden Stufen/XP-Aufstieg das Skript dann einmal durchlaufen wird. Aber der letzte Block sollte das doch verhindern, wenn die BE_LevelUp Variable auf 1 gesetzt wird kann das Skript nie wieder laufen, oder? Bzw. schon, aber es passiert nichts.

Da ich aber schon Jasteys Mods gespielt habe und mir ziemlich sicher bin, dass da der Stufenaufstieg über mehrere Stufen klappt, bin ich ein wenig irritiert.

Und ich hätte die Skriptblöcke einfach in anderer Reihenfolge genutzt: also zuerst nach "Level 1" fragen, und wenn ja, dann die XP für "Level 2" geben, dann abfragen ob es mit dem nächsten weitergehen soll etc. Dann würde das Skript nur einmal laufen und zwar so lange, bis das Ziel-Level erreicht ist.

Aber da ich ja offensichtlich einen Denkfehler drin habe: welcher ist es?

 

[Argent]

Du hättest Recht, wenn die Skriptblöcke alle mit Continue() abschließen würden. Dann würde das Skript bis zum Ende durchlaufen und damit auch den letzten Block erreichen und ausführen.

Da diese Aktion fehlt, wird nur der jeweils erste zutreffende Block ausgeführt, und dann wird der Skriptdurchlauf neu gestartet. Der letzte Block mit der "C#BE_LevelUp" Variable wird also nur erreicht, wenn alle anderen Blöcke vorher nicht (mehr) zutreffen.

 

[Maus]

Ähm ja, genau. *hust*

Danke

 

[Jastey]

Da wir grad dabei sind. ich weiß auch nicht mehr, warum ich die Blöcke nicht in die "richtige" Reihenfolge gesetzt habe und mit Continue() gearbeitet habe. Das würde dann denselben Effekt haben, oder?
Wäre das effizienter?

 

[Argent]

Mit Continue() müsste man die Skriptblöcke komplett umschreiben, da alle Bedingungen nur einmal pro Skriptdurchgang ausgewertet werden. Es wären wahrscheinlich deutlich mehr Blöcke notwendig, um alle Fälle abzudecken. Die jetzige Implementierung benötigt zwar mehrere Skriptdurchgänge, ist dafür aber recht kompakt geschrieben.

 

[Maus]

Ich hätte da eine Idee und könnte das vielleicht heute abend mal aufschreiben... Dann könntet ihr schauen, ob das funktionieren würde

 

[Maus]

So, neue Frage: ich möchte die folgende Cut-Scene so erweitern, dass noch mehr Kreaturen erzeugt werden. Der Syntax dafür sollte nicht das Problem sein. Nur: wie bekomme ich den Code in(!) die Cur-Scene hinein?

IF
    True()
THEN
    RESPONSE #100
        CutSceneId(Player1)
        FadeToColor([20.0],0)
        Wait(2)
        MoveViewPoint([2713.2093],INSTANT)
        JumpToPoint([2713.2093])
        ActionOverride(Player2,JumpToPoint([2679.1997]))
        ActionOverride(Player3,JumpToPoint([2729.1986]))
        ActionOverride(Player4,JumpToPoint([2665.2059]))
        ActionOverride(Player5,JumpToPoint([2712.2043]))
        ActionOverride(Player6,JumpToPoint([2760.2045]))
        Face(SE)
        ActionOverride(Player2,Face(SE))
        ActionOverride(Player3,Face(SE))
        ActionOverride(Player4,Face(SE))
        ActionOverride(Player5,Face(SE))
        ActionOverride(Player6,Face(SE))
        ActionOverride("Aldeth",Face(SE))
        FadeFromColor([20.0],0)
        Wait(2)
        CreateCreature("DRUID3",[2966.2428],NE)  // Druid
        ActionOverride("Druid3",MoveToPoint([2648.2200]))
        ActionOverride("Druid3",Face(NNE))
        CreateCreature("DRUID3",[3048.2379],NE)  // Druid
        ActionOverride("Druid3",MoveToPoint([2720.2207]))
        CreateCreature("DRUID3",[3114.2324],NE)  // Druid
        ActionOverride("Druid3",MoveToPoint([2813.2120]))
        CreateCreature("SENIYA",[3133.2387],NE)  // Seniyad
        ActionOverride("Seniyad",MoveToPoint([2695.2130]))
        ActionOverride("Seniyad",Dialogue([PC]))
END

Und falls das nicht geht: ich habe da ja keine Möglichkeit zu triggern, erst wieder in dem Dialog, der da statt findet oder schon vor der CutScene. Wobei letzteres vielleicht eine gute Idee wäre...

 

[Jastey]

Über patchen über einen eindeutig zu erkennenden Textschnipsel. Beispiel aus Imoen4Ever:

COPY_EXISTING ~bd0120.BCS~ ~override~
    DECOMPILE_AND_PATCH BEGIN
        SPRINT textToReplace ~\(InPartyAllowDead("imoen2?")\)~
        COUNT_REGEXP_INSTANCES ~%textToReplace%~ num_matches
        PATCH_IF (num_matches > 0) BEGIN
            REPLACE_TEXTUALLY CASE_INSENSITIVE ~%textToReplace%~ ~\1 Global("C#st_ImoenInGroupKD","GLOBAL",0)~
            PATCH_PRINT ~Patching: %num_matches% matches found in %SOURCE_FILESPEC% for REPLACE_TEXTUALLY: %textToReplace%~
        END ELSE BEGIN
            PATCH_WARN ~WARNING: could not find %textToReplace% in %SOURCE_FILESPEC%~
        END
        SPRINT textToReplace ~\(!InMyArea("imoen2?")\)~
        COUNT_REGEXP_INSTANCES ~%textToReplace%~ num_matches
        PATCH_IF (num_matches > 0) BEGIN
            REPLACE_TEXTUALLY ~%textToReplace%~ ~\1 !Global("C#st_ImoenInGroupKD","GLOBAL",1)~
            PATCH_PRINT ~Patching: %num_matches% matches found in %SOURCE_FILESPEC% for REPLACE_TEXTUALLY: %textToReplace%~
        END ELSE BEGIN
            PATCH_WARN ~WARNING: could not find %textToReplace% in %SOURCE_FILESPEC%~
        END
        SPRINT textToReplace ~\(ActionOverride("imoen2?",JumpToPoint(\[1770\.1520\]))[%newline%]*ActionOverride("imoen2?",Face(N))\)~
        COUNT_REGEXP_INSTANCES ~%textToReplace%~ num_matches
        PATCH_IF (num_matches > 0) BEGIN
            REPLACE_TEXTUALLY ~%textToReplace%~ ~SetGlobal("C#st_ImoenMoveInCrypt","GLOBAL",1)~
            PATCH_PRINT ~Patching: %num_matches% matches found in %SOURCE_FILESPEC% for REPLACE_TEXTUALLY: %textToReplace%~
        END ELSE BEGIN
            PATCH_WARN ~WARNING: could not find %textToReplace% in %SOURCE_FILESPEC%~
        END
        SPRINT textToReplace ~\(ActionOverride("imoen2?",JumpToPoint(\[1545\.700\]))[%newline%]*ActionOverride("imoen2?",Face(NE))\)~
        COUNT_REGEXP_INSTANCES ~%textToReplace%~ num_matches
        PATCH_IF (num_matches > 0) BEGIN
            REPLACE_TEXTUALLY ~%textToReplace%~ ~SetGlobal("C#st_ImoenMoveInCrypt","GLOBAL",2)~
            PATCH_PRINT ~Patching: %num_matches% matches found in %SOURCE_FILESPEC% for REPLACE_TEXTUALLY: %textToReplace%~
        END ELSE BEGIN
            PATCH_WARN ~WARNING: could not find %textToReplace% in %SOURCE_FILESPEC%~
        END
    END
BUT_ONLY

 

[Maus]

Ah ok, über Text ersetzen. Gut, das würde wahrscheinlich gehen. Die letzten zwei Zeilen bieten sich dafür an. Und ich weiß, dass ich es nur einmal ersetze, somit könnte ich mir die num_matches sparen. Aber ich sehe gerade beim Nachdenken, dass ich das wahrscheinlich für den Syntax benötige, um die entsprechende WARNING zu erzeugen.

Vom Prinzip her würde aber SPRINT und REPLACE TEXTUALLY ausreichen, oder? Und das BUT_ONLY frägt die Existenz des Skripts an sich ab, richtig?

 

[Jastey]

BUT_ONLY steht für BUT_ONLY_IF_IT_CHANGES und bewirkt, dass das Patchen nur durchlaufen wird, wenn es tatsächlich was ändert. (Ist bei regexp interessant wiel es dann schneller geht falls nichts gepacht werden muss).
Das Patchen wie hier gezeigt gibt leider einen Installationsfehler wenn man diesen nicht abfängt. Dazu ist der Überbau mit der Warnung da, übrigens von @Argent mal für mich bereitgestellt (glaube ich?).
So wie es hier gemacht wird kann es auch mal sein, dass bei einem Spieler das Patchen nicht klappt, ohne, dass gleich die ganze Mod nicht installiert werden kann.

 

[Maus]

Folgendes Skript hat nicht funktioniert:

COPY_EXISTING ~ALDCUT01.BCS~ ~override~
    DECOMPILE_AND_PATCH 
    BEGIN
        SPRINT textToReplace ~CreateCreature("SENIYA",[3133.2387],NE)~
        COUNT_REGEXP_INSTANCES ~%textToReplace%~ num_matches
        PATCH_IF (num_matches > 0) 
        BEGIN
            REPLACE_TEXTUALLY CASE_INSENSITIVE ~%textToReplace%~ ~CreateCreature("SENIYA",[3133.2387],NE) \n CreateCreature("M8MERAN1",[3142.2397],NE) \n ActionOverride("M8MERAN1",MoveToPoint([2648.2250])) \n CreateCreature("M8MERAN2",[3153.2376],NE) \n ActionOverride("M8MERAN2",MoveToPoint([2700.2180])) \n CreateCreature("M8MERAN3",[3127.2400],NE) \n ActionOverride("M8MERAN2",MoveToPoint([2730.2175]))~
            PATCH_PRINT ~Patching: %num_matches% matches found in %SOURCE_FILESPEC% for REPLACE_TEXTUALLY: %textToReplace%~
        END 
        ELSE BEGIN
            PATCH_WARN ~WARNING: could not find %textToReplace% in %SOURCE_FILESPEC%~
        END
    END
BUT_ONLY

Es hat die ELSE Warning ausgegeben...

 

[Argent]

SPRINT textToReplace ~CreateCreature("SENIYA",[3133.2387],NE)~

Der Suchstring muss als regulärer Ausdruck angegeben werden. Die eckigen Klammern und der Trennungspunkt sind spezielle Symbole und müssen daher "escaped" werden. Alternativ kann man für REPLACE_TEXTUALLY auch die Option "EXACT_MATCH" angeben. Dann wird der Suchstring wie ein normaler String behandelt.

Einen weiteren Fehler sehe ich im Ersetzungstext von REPLACE_TEXTUALLY. Symbole für Zeilenumbrüche (\n) kennt WeiDU nicht. Die muss man mit der Variable %LNL% oder %WNL% angeben. Die kann man aber auch ganz weglassen, da sie durch das Kompilieren sowieso entfernt werden.

 

[Jastey]

Wie Argent schon schrieb, Du musst eckige Klammern und Punkte im zu erkennenden Text mit einem \ markieren, sonst verhaspelt es sich. Auch macht das \n keinen Sin, Du kannst einfach was Du reinschreiben möchtest hinschreiben:

COPY_EXISTING ~ALDCUT01.BCS~ ~override~
    DECOMPILE_AND_PATCH
    BEGIN
        SPRINT textToReplace ~CreateCreature("SENIYA",\[3133.2387\],NE)~
        COUNT_REGEXP_INSTANCES ~%textToReplace%~ num_matches
        PATCH_IF (num_matches > 0)
        BEGIN
            REPLACE_TEXTUALLY CASE_INSENSITIVE ~%textToReplace%~ ~CreateCreature("SENIYA",[3133.2387],NE)
    CreateCreature("M8MERAN1",[3142.2397],NE)
    ActionOverride("M8MERAN1",MoveToPoint([2648.2250]))
    CreateCreature("M8MERAN2",[3153.2376],NE)
    ActionOverride("M8MERAN2",MoveToPoint([2700.2180]))
    CreateCreature("M8MERAN3",[3127.2400],NE)
    ActionOverride("M8MERAN2",MoveToPoint([2730.2175]))~
            PATCH_PRINT ~Patching: %num_matches% matches found in %SOURCE_FILESPEC% for REPLACE_TEXTUALLY: %textToReplace%~
        END
        ELSE BEGIN
            PATCH_WARN ~WARNING: could not find %textToReplace% in %SOURCE_FILESPEC%~
        END
    END
BUT_ONLY

Die muss man mit der Variable %LNL% oder %WNL% angeben.

Müssen tut man das nur für den zu erkennenden Text. Bei dem zu scheibenden habe ich immer so formatiert hingeschrieben, wie es reingepatcht werden soll.